48f2c9dbba
It is not generally true that `CMAKE_INSTALL_<dir>` variables are relative paths: https://github.com/jtojnar/cmake-snips#concatenating-paths-when-building-pkg-config-files https://github.com/jtojnar/cmake-snips#assuming-cmake_install_dir-is-relative-path Let's join them properly as paths, not strings. On Windows, the absolute paths will likely remain unsupported as neither the CMake function, nor the C++ code is able to detect absolute paths. Signed-off-by: Jan Tojnar <jtojnar@gmail.com>
25 lines
842 B
CMake
25 lines
842 B
CMake
# This module provides function for joining paths
|
||
# known from from most languages
|
||
#
|
||
# Original license:
|
||
# SPDX-License-Identifier: (MIT OR CC0-1.0)
|
||
# Copyright 2020 Jan Tojnar
|
||
# https://github.com/jtojnar/cmake-snips
|
||
#
|
||
# Modelled after Python’s os.path.join
|
||
# https://docs.python.org/3.7/library/os.path.html#os.path.join
|
||
# Windows not supported
|
||
function(join_paths joined_path first_path_segment)
|
||
set(temp_path "${first_path_segment}")
|
||
foreach(current_segment IN LISTS ARGN)
|
||
if(NOT ("${current_segment}" STREQUAL ""))
|
||
if(IS_ABSOLUTE "${current_segment}")
|
||
set(temp_path "${current_segment}")
|
||
else()
|
||
set(temp_path "${temp_path}/${current_segment}")
|
||
endif()
|
||
endif()
|
||
endforeach()
|
||
set(${joined_path} "${temp_path}" PARENT_SCOPE)
|
||
endfunction()
|